iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion limpiar como
  inicio
    mientras frente-libre hacer
      inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        avanza;
      fin;
  fin;

define-nueva-instruccion irpunta como
  inicio
    norte;
    mientras junto-a-zumbador hacer avanza;
    sur;
    avanza;
    norte;
    mientras junto-a-zumbador hacer coge-zumbador;
  fin;

define-nueva-instruccion siguiente como
  inicio
    este;
    si frente-libre entonces
      inicio
        avanza;
      fin
    sino
      inicio
        norte;
        mientras derecha-bloqueada hacer avanza;
        este;
        avanza;
        sur;
      fin;
  fin;

define-nueva-instruccion dejar como
  inicio
    oeste;
    avanza;
    sur;
    mientras frente-libre hacer avanza;
  fin;

define-nueva-instruccion contar(n) como
  inicio
    si junto-a-zumbador entonces
      inicio
       coge-zumbador;
       contar(sucede(n));
      fin
    sino
      inicio
        avanza;
        repetir n veces si junto-a-zumbador entonces coge-zumbador;
        si junto-a-zumbador entonces
          inicio
            avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            sur;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
          fin
        sino
          inicio
           repetir n veces deja-zumbador;
           mientras algun-zumbador-en-la-mochila hacer
             inicio
               coge-zumbador;
               avanza;
               repetir 2 veces deja-zumbador;
               sur;
               avanza;
               norte;
             fin;
           mientras junto-a-zumbador hacer coge-zumbador;
           sur;
           avanza;
           avanza;
           este;
           mientras frente-libre hacer avanza;
           norte;
           mientras derecha-bloqueada hacer avanza;
           este;
           avanza;
           mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
           dejar;
          fin;
      fin;
  fin;



define-nueva-instruccion ver(n) como
  inicio
   si frente-libre entonces
     inicio
       avanza;
       ver(sucede(n));
     fin
   sino
     inicio
       oeste;
       repetir n veces avanza;
        norte;
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
        este;
        avanza;
        norte;
        mientras no orientado-al-sur hacer
          inicio
            irpunta;
            siguiente;
          fin;
        dejar;
        oeste;
        repetir n veces avanza;
        norte;
        repetir 2 veces avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        sur;
        avanza;
        norte;
     fin;
  fin;
  inicia-ejecucion
        este;
        ver(0);
        contar(0);
        norte;
        avanza;
        limpiar;
        apagate;
    termina-ejecucion
finalizar-programa
