iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion avanzar como inicio
        norte;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        avanza;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-norte entonces inicio
                sur;
                coge-zumbador;
            fin sino inicio
                norte;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoger como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger;
            deja-zumbador;
        fin sino inicio
            sur;
            si frente-bloqueado entonces deja-zumbador;
            mientras frente-libre hacer avanza;
            este;
            si frente-libre entonces inicio
                avanza;
                avanzar;
                recoger;
            fin sino inicio
                oeste;
                mientras frente-libre hacer avanza;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                    este;
                    avanza;
                    deja-zumbador;
                    oeste;
                    avanza;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion llevar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llevar;
            deja-zumbador;
        fin sino inicio
            este;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            oeste;
            si junto-a-zumbador y frente-libre entonces avanza;

        fin;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            contar(sucede(n));
        fin sino inicio
            repetir n veces coge-zumbador;
            recoger;
            comparar(n);
            si orientado-al-norte entonces inicio
                norte;
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
                sur;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                este;
                mientras frente-libre hacer avanza;
                norte;
                mientras derecha-bloqueada y frente-libre hacer avanza;
                este;
                avanza;
                mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            fin sino inicio
                llevar;
            fin;
            apagate;
        fin;
    fin;

    inicia-ejecucion
        mientras no junto-a-zumbador hacer avanza;
        avanzar;
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
