iniciar-programa
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer  gira-izquierda;

define-nueva-instruccion sur como
    mientras no orientado-al-sur hacer  gira-izquierda;

define-nueva-instruccion oeste como
    mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;

define-nueva-instruccion subir como inicio
    mientras frente-libre hacer  avanza;
    norte;
    mientras derecha-bloqueada y frente-libre hacer  avanza;
    sur;
fin;
define-nueva-instruccion siguiente como inicio
    oeste;
    avanza;
    sur;
    mientras no junto-a-zumbador y frente-libre hacer avanza;
 fin;
define-nueva-instruccion vitaminas(v) como inicio
    si algun-zumbador-en-la-mochila entonces inicio
         deja-zumbador;
         vitaminas(sucede(v));

    fin sino inicio
         repetir v veces coge-zumbador;
         repetir v veces inicio
             si junto-a-zumbador entonces inicio
                 coge-zumbador;
             fin;
         fin;
         si no junto-a-zumbador entonces inicio
             repetir v veces deja-zumbador;
             norte;
         fin;
    fin;
fin;
define-nueva-instruccion sobra(s) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sobra(sucede(s));

    fin sino inicio
        subir;
        gira-izquierda;
        si frente-libre entonces avanza;
        repetir s veces deja-zumbador;
    fin;
fin;
define-nueva-instruccion recoger(n) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        recoger(sucede(n));

    fin sino inicio
        siguiente;
        si frente-libre o junto-a-zumbador entonces inicio
            recoger(n);
        fin sino inicio
            repetir n veces deja-zumbador;
            vitaminas(0);
        fin;

        si orientado-al-norte entonces inicio
            repetir n veces inicio
                si junto-a-zumbador entonces  coge-zumbador;
            fin;
            este;
            sobra(0);
        fin;
    fin;
fin;
    inicia-ejecucion
        subir;
        mientras no junto-a-zumbador hacer avanza;
        recoger(0);
        apagate;
    termina-ejecucion
finalizar-programa
