iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion pasos(x) como inicio
        si frente-libre entonces inicio
            avanza;
            pasos(sucede(x));
        fin sino inicio
            oeste;
            mientras junto-a-zumbador y no-orientado-al-este hacer inicio
                norte;
                mientras junto-a-zumbador hacer avanza;
                sur;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                mientras frente-libre hacer avanza;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    este;
                fin;
            fin;
            este;
            corre;
            oeste;
            repetir x veces avanza;
        fin;
    fin;
    define-nueva-instruccion quita(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            quita(precede(x));
        fin sino inicio
            si no si-es-cero(x) entonces inicio
                este;
                corre;
                norte;
                mientras derecha-bloqueada hacer avanza;
                este;
                avanza;
                repetir x veces deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion deja(x) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
            deja(sucede(x));
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            este;
            pasos(0);
            mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
            repetir x veces coge-zumbador;
            quita(x);
        fin;
    fin;
    inicia-ejecucion
        deja(0);
        apagate;
    termina-ejecucion
finalizar-programa

