iniciar-programa

define-nueva-instruccion gira-d como repetir 3 veces gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanza-muro como mientras frente-libre hacer avanza;
define-nueva-instruccion avanza-zumbador como mientras junto-a-zumbador hacer avanza;

define-nueva-instruccion falto(n) como
inicio
    si algun-zumbador-en-la-mochila entonces
    inicio
        deja-zumbador;
        falto(sucede(n));
    fin
    sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        oeste;
        avanza-muro;
        sur;
        avanza-muro;
        este;
        mientras no-junto-a-zumbador hacer avanza;
        repetir n veces deja-zumbador;
        coge-zumbador;
        apagate;
    fin;                                           
fin;

define-nueva-instruccion final(n) como
inicio
    si algun-zumbador-en-la-mochila entonces
    inicio
        deja-zumbador;
        final(sucede(n));
    fin
    sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir n veces deja-zumbador;
        apagate;
    fin;
fin;

define-nueva-instruccion sobro(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        sobro(sucede(n));
    fin
    sino inicio
        repetir 2 veces
        inicio
            repetir n veces deja-zumbador;
        fin;
        final(0);
    fin;
fin;

define-nueva-instruccion comparar(n) como
inicio
    repetir n veces
    inicio
        si algun-zumbador-en-la-mochila entonces deja-zumbador;
    fin;
    si algun-zumbador-en-la-mochila entonces
    inicio
        falto(0);
    fin
    sino inicio
        repetir n veces coge-zumbador;
        sobro(0);
    fin;
fin;

define-nueva-instruccion contar-vitaminas(n) como
inicio
    sur;
    avanza-muro;
    este;
    avanza;
    norte;
    si derecha-libre entonces
    inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si no junto-a-zumbador entonces
        inicio
        sur;
        avanza;
        fin;
        mientras junto-a-zumbador hacer coge-zumbador;
        contar-vitaminas(n);
    fin
    sino inicio
        avanza;
        mientras junto-a-zumbador hacer avanza;
        sur;
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        norte;
        avanza;
        este;
        avanza;
        repetir n veces deja-zumbador;
        comparar(n);
    fin;
fin;

define-nueva-instruccion contar-mochila(n) como
inicio
    si algun-zumbador-en-la-mochila entonces
    inicio
        deja-zumbador;
        contar-mochila(sucede(n));
    fin
    sino inicio
        mientras junto-a-zumbador hacer coge-zumbador;
        deja-zumbador;
        contar-vitaminas(n);
    fin;
fin;

define-nueva-instruccion medir-distancia(n) como
inicio
    este;
    si frente-libre entonces
    inicio
        avanza;
        medir-distancia(sucede(n));
    fin
    sino inicio
        coge-zumbador;
        oeste;
        repetir n veces avanza;
        deja-zumbador;
        este;
    fin;
fin;

    inicia-ejecucion
        medir-distancia(0);
        contar-mochila(0);
        apagate;
    termina-ejecucion
finalizar-programa
