iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion dejar como inicio
         si algun-zumbador-en-la-mochila entonces inicio
            norte;
            mientras derecha-bloqueada hacer inicio
                avanza;
            fin;
            este;
            avanza;
            mientras algun-zumbador-en-la-mochila hacer inicio
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion ubicar como inicio
        norte;
        mientras junto-a-zumbador hacer inicio
            avanza;
        fin;
        sur;
        avanza;
        este;
    fin;
    define-nueva-instruccion contar como inicio
        si junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
            coge-zumbador;
            norte;
            avanza;
            deja-zumbador;
            deja-zumbador;
            sur;
            avanza;
            contar;
        fin sino inicio
            si algun-zumbador-en-la-mochila entonces inicio
                este;
                si frente-libre entonces inicio
                    avanza;
                    si derecha-libre o junto-a-zumbador entonces inicio
                        norte;
                        mientras junto-a-zumbador hacer inicio
                            avanza;
                        fin;
                        sur;
                        avanza;
                        este;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoge como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge;
        fin sino inicio
            este;
            si frente-libre entonces inicio
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
                avanza;
                norte;
                mientras junto-a-zumbador hacer inicio
                    avanza;
                fin;
                sur;
                avanza;
            fin sino inicio
                sur;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                oeste;
                mientras frente-libre hacer inicio
                    avanza;
                fin;
                este;
                mientras no junto-a-zumbador hacer inicio
                    avanza;
                fin;
                mientras algun-zumbador-en-la-mochila hacer inicio
                    deja-zumbador;
                fin;
                coge-zumbador;
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        deja-zumbador;
        avanza;
        ubicar;
        mientras algun-zumbador-en-la-mochila y junto-a-zumbador hacer inicio
            contar;
        fin;
        norte;
        avanza;
        coge-zumbador;
        sur;
        avanza;
        contar;
        contar;
        mientras junto-a-zumbador o ningun-zumbador-en-la-mochila hacer inicio
            recoge;
        fin;
        dejar;
        apagate;
    termina-ejecucion
finalizar-programa
