iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion ubica como inicio
        mientras frente-libre hacer avanza;
        gira(1);
        mientras derecha-bloqueada hacer avanza;
        gira(3);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        gira(2);
        avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(3);
        mientras junto-a-zumbador hacer avanza;
        gira(2);
        si no-junto-a-zumbador entonces avanza;
        fin;
    define-nueva-instruccion mueve como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve;
            deja-zumbador;
            fin
            sino inicio
            avanza;
            fin;
        fin;
    define-nueva-instruccion bajar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            bajar;
            deja-zumbador;
            fin
            sino inicio
            avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(3);
            mientras junto-a-zumbador hacer avanza;
            fin;
        fin;
    define-nueva-instruccion comparar como inicio
        si no-junto-a-zumbador entonces inicio
            avanza;
            apagate;
            fin;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanza;
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
                gira(2);
                avanza;
                gira(2);
                mueve;
                mientras no-orientado-al-oeste hacer gira-izquierda;
                bajar;
                apagate;
                fin;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                gira(2);
                avanza;
                gira(2);
                comparar;
                fin;
            fin;
        fin;
    define-nueva-instruccion cuenta(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(x));
            fin;
        si no-junto-a-zumbador entonces inicio
            mientras frente-libre hacer inicio
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                fin;
            deja-zumbador;    
            gira(1);
            si frente-bloqueado entonces inicio
                gira(1);
                mientras frente-libre y derecha-bloqueada hacer avanza;
                gira(3);
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir x veces deja-zumbador;
                comparar;
                apagate;
                fin;
            si frente-libre entonces inicio
                avanza;
                gira(1);
                mientras frente-libre y junto-a-zumbador hacer avanza;
                gira(2);                 
                si no-junto-a-zumbador entonces avanza;
                cuenta(x);
                fin;
            fin;
        fin;
    inicia-ejecucion
        ubica;
        mientras no-orientado-al-norte hacer gira-izquierda;
        mientras frente-libre y junto-a-zumbador hacer avanza;
        gira(2);
        si no-junto-a-zumbador entonces avanza;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
