iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ubicar como
inicio
  mientras no-junto-a-zumbador y frente-libre hacer avanza;
  si junto-a-zumbador entonces
    inicio
      norte;
      mientras junto-a-zumbador y frente-libre hacer avanza;
      sur;
      si no-junto-a-zumbador entonces avanza;
      norte;
    fin
  sino apagate;
fin;

define-nueva-instruccion escalar(n) como
inicio
  si junto-a-zumbador y no si-es-cero(n) entonces
    inicio
      coge-zumbador;
      escalar(precede(n));
    fin
  sino
    inicio
      si no si-es-cero(n) entonces
        inicio
          este;
          si frente-libre entonces
            inicio
              avanza;
              norte;
              mientras frente-libre  y junto-a-zumbador hacer avanza;
              sur;
              si no-junto-a-zumbador entonces avanza;
              norte;
              escalar(n);
            fin
          sino
            inicio
              norte;
              mientras derecha-bloqueada hacer avanza;
              este;
              avanza;
              repetir n veces deja-zumbador;
              apagate;
            fin;
        fin;
    fin;
fin;

define-nueva-instruccion ir_abajo como
inicio
  sur;
  mientras frente-libre hacer avanza;
  oeste;
  mientras junto-a-zumbador y frente-libre hacer avanza;
  si junto-a-zumbador entonces
    inicio
      mientras junto-a-zumbador hacer coge-zumbador;
    fin;
fin;

define-nueva-instruccion faltan(n) como
inicio
  si junto-a-zumbador entonces
    inicio
      coge-zumbador;
      faltan(sucede(n));
    fin
  sino
    inicio
      este;
      si frente-libre entonces
        inicio
          avanza;
          norte;
          mientras junto-a-zumbador y frente-libre hacer avanza;
          sur;
          si no-junto-a-zumbador entonces avanza;
          norte;
          faltan(n);
        fin
      sino
        inicio
          ir_abajo;
          repetir n veces deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion mochila(n) como
inicio
  si algun-zumbador-en-la-mochila entonces
    inicio
      deja-zumbador;
      mochila(sucede(n));
    fin
  sino
    inicio
      repetir n veces coge-zumbador;
      ubicar;
      si no si-es-cero(n) entonces escalar(n);
      si no-orientado-al-este entonces faltan(0);
    fin;
fin;

define-nueva-instruccion tomar(i) como
inicio
  si junto-a-zumbador entonces
    inicio
      coge-zumbador;
      tomar(i);
      deja-zumbador;
    fin
  sino
    inicio
      este;
      mientras frente-libre hacer avanza;
      oeste;
      repetir i veces avanza;
    fin;
fin;

define-nueva-instruccion contar(i) como
inicio
  si frente-libre entonces
    inicio
      avanza;
      contar(sucede(i));
    fin
  sino
    inicio
      oeste;
      repetir i veces avanza;
      este;
      mochila(0);
      tomar(i);
    fin;
fin;

    inicia-ejecucion
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
