iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion montana como inicio
        mientras junto-a-zumbador hacer
            avanza;
        gira (2);
        avanza;
        mientras junto-a-zumbador hacer
            coge-zumbador;
        mientras frente-libre hacer
            avanza;
        gira (1);
    fin;
    define-nueva-instruccion falta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            falta (sucede(n));
        fin
        sino inicio
            gira (2);
            avanza;
            mientras junto-a-zumbador hacer
                coge-zumbador;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cima (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cima (sucede(n));
        fin
        sino inicio
            gira (1);
            mientras frente-libre hacer
                avanza;
            gira (1);
            mientras derecha-bloqueada hacer
                avanza;
            gira (3);
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion sobra (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sobra (sucede(n));
        fin
        sino inicio
            gira (2);
            avanza;
            repetir n veces
                coge-zumbador;
            cima (0);
        fin;
    fin;
    define-nueva-instruccion vitaminas (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            vitaminas (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces
                    coge-zumbador;
            fin;
            si junto-a-zumbador entonces inicio
                falta (0);
            fin
            sino inicio
                mientras algun-zumbador-en-la-mochila hacer
                    deja-zumbador;
                sobra (0);
            fin;
        fin;
    fin;
    inicia-ejecucion
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        gira (2);
        avanza;
        gira (2);
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        avanza;
        mientras frente-libre hacer inicio
            gira (1);
            montana;
            avanza;
        fin;
        gira (1);
        montana;
        gira (2);
        mientras frente-libre hacer
            avanza;
        gira (2);
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        gira (1);
        avanza;
        mientras algun-zumbador-en-la-mochila hacer
            deja-zumbador;
        gira (2);
        avanza;
        gira (2);
        vitaminas (0);
        apagate;
    termina-ejecucion
finalizar-programa