iniciar-programa

define-nueva-instruccion gira(z) como repetir z veces gira-izquierda;

define-nueva-instruccion multiplicar(c) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        multiplicar(c);
        repetir c veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion multiplicar_aux(b) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;                  
        multiplicar_aux(sucede(b));
    fin sino inicio
        repetir precede(b) veces deja-zumbador;
        repetir 2 veces avanza;
        multiplicar(b);
        gira(2);
        repetir 2 veces avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion contar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        contar(sucede(a));
    fin sino inicio
        gira(2);
        avanza;
        deja-zumbador;
        gira(2);
        repetir 2 veces avanza;
        gira(2);

        mientras junto-a-zumbador hacer inicio
            repetir a veces coge-zumbador;
            si junto-a-zumbador entonces inicio
                repetir a veces deja-zumbador;
                multiplicar_aux(0);
            fin sino apagate;
        fin;
    fin;
fin;

    inicia-ejecucion

        avanza;
        contar(0);


        apagate;
    termina-ejecucion
finalizar-programa
