iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion multiplica(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplica(x);
            repetir x veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion crece(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sur;
            avanza;
            multiplica(x);
            norte;
            avanza;
            crece(precede(x));
        fin;
    fin;
    define-nueva-instruccion leer(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            leer(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            norte;
            avanza;
            crece(precede(x));
        fin;
    fin;
    define-nueva-instruccion quita(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(precede(x));
        fin sino inicio
            si no si-es-cero(x) entonces inicio
                repetir precede(x) veces deja-zumbador;
                sur;
                avanza;
                leer(0);
            fin sino inicio
                sur;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion resta(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta(sucede(x));
        fin sino inicio
            sur;
            corre;
            norte;
            repetir x veces deja-zumbador;
            avanza;
            quita(x);
        fin;
    fin;
    inicia-ejecucion
        norte;
        repetir 2 veces avanza;
        resta(0);
        apagate;
    termina-ejecucion
finalizar-programa
