iniciar-programa
    define-nueva-instruccion gira(z) como inicio
        repetir z veces gira-izquierda;
    fin;
    define-nueva-instruccion lugar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lugar(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(2);
            si no si-es-cero(n) entonces repetir precede(n) veces avanza;
            si no-junto-a-zumbador entonces repetir n veces deja-zumbador sino inicio
                mientras no-orientado-al-sur hacer gira-izquierda;
                mientras junto-a-zumbador hacer coge-zumbador;
                mientras frente-libre hacer avanza;
                gira(2);
                deja-zumbador;
                apagate;
            fin;
        fin;
    fin;
    define-nueva-instruccion iguales(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            iguales(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            repetir n veces deja-zumbador;
            si frente-libre entonces avanza;
            si no-junto-a-zumbador entonces inicio
                iguales(precede(n));
                sal-de-instruccion;
            fin sino inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                sal-de-instruccion;
            fin;
        fin;
    fin;
    define-nueva-instruccion segundo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            segundo(n);
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion multiplicacion(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplicacion(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            avanza;
            si junto-a-zumbador entonces segundo(n) sino inicio
                mientras frente-libre hacer avanza;
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion resultado(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resultado(sucede(n));
            sal-de-instruccion;
        fin;
        si no-junto-a-zumbador entonces inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
inicia-ejecucion
    repetir 2 veces avanza;
    lugar(0);
    gira(2);
    mientras frente-libre hacer avanza;
    gira(2);
    avanza;
    lugar(0);
    si frente-libre entonces avanza;
    mientras no-junto-a-zumbador hacer avanza;
    gira(2);
    iguales(0);
    gira(2);
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si frente-libre entonces inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si no-junto-a-zumbador entonces avanza;
        mientras junto-a-zumbador y frente-libre hacer multiplicacion(0);
    fin sino resultado(0);
        apagate;
    termina-ejecucion
finalizar-programa
