iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion correr(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        correr(sucede(a));
    fin sino inicio
        si orientado-al-este entonces inicio
            repetir precede(a) veces deja-zumbador;
            avanza;
            repetir a veces deja-zumbador;
            gira(2);
            correr(0);
        fin sino inicio
        repetir precede(a) veces deja-zumbador;
            avanza;
            gira(1);
            repetir 2 veces avanza;
            gira(2);
            repetir a veces deja-zumbador;
            repetir 2 veces avanza;
            gira(3);
        fin;
    fin;
fin;

define-nueva-instruccion resta(b)como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        resta(sucede(b));
    fin sino inicio
        avanza;
        repetir b veces coge-zumbador;
        gira(3);
        avanza;
        repetir b veces deja-zumbador;
        gira(2);
        avanza;
        gira(2);
        correr(0);
    fin;
fin;

define-nueva-instruccion producto(c) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        producto(sucede(c));
    fin sino inicio
        repetir c veces deja-zumbador;
        gira(3);
        repetir 2 veces avanza;
        gira(3);
        avanza;
        gira(3);
        repetir c veces deja-zumbador;
        repetir 2 veces avanza;
        gira(3);
    fin;
fin;

define-nueva-instruccion factorial(d) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        factorial(sucede(d));
    fin sino inicio
        repetir 2 veces avanza;
        gira(3);
        repetir d veces inicio
            avanza;
            producto(0);
        fin;
        avanza;
        coge-zumbador;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

    inicia-ejecucion

    avanza;
    resta(0);
    mientras junto-a-zumbador hacer inicio
        coge-zumbador;
        gira(3);
        repetir 2 veces avanza;
        gira(2);
        factorial(0);
    fin;

        apagate;
    termina-ejecucion
finalizar-programa
