iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion formar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            formar(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            avanza;
        fin;
    fin;
    define-nueva-instruccion tomar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            tomar(n);
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion multiplicar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplicar(sucede(n));
        fin sino inicio
            avanza;
            tomar(n);
        fin;
    fin;

    define-nueva-instruccion piramides(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            piramides(sucede(n));
        fin sino inicio
            sur;
            avanza;
            este;
            repetir precede(n) veces inicio
                formar(0);
                coge-zumbador;
            fin;
            oeste;
            mientras frente-libre hacer inicio
                multiplicar(0);
            fin;
        fin;
    fin;

    define-nueva-instruccion pasar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasar(sucede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces inicio
                deja-zumbador;
            fin;
            avanza;
        fin;
    fin;

    define-nueva-instruccion restar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            restar;
            coge-zumbador;
        fin sino inicio
            avanza;
            pasar(0);
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ir11;
            deja-zumbador;
        fin sino inicio
            sur;
            avanzA;
            avanza;
        fin;
    fin;

    inicia-ejecucion
        norte;
        avanza;
        restar;
        piramides(0);
        ir11;
        apagate;
    termina-ejecucion
finalizar-programa
