iniciar-programa
      define-nueva-instruccion g(n) como
        repetir n veces
            gira-izquierda;
    define-nueva-instruccion res(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            res(sucede(n));

        fin
        sino
        inicio
            avanza;
            repetir n veces
            inicio
                coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion aco(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            aco(sucede(n));
        fin
        sino
        inicio
            g(2);
            avanza;
            g(1);
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion mult(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            mult(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            g(1);
            mientras junto-a-zumbador hacer
            inicio
                coge-zumbador;
                avanza;
                repetir n veces
                    deja-zumbador;
                g(2);
                avanza;
                g(2);
            fin;
            avanza;
            aco(0);
        fin;
    fin;
    define-nueva-instruccion dupa(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            dupa(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            si frente-bloqueado entonces
                g(1);
            avanza;

            repetir n veces
                deja-zumbador;
            g(2);
            avanza;
            g(2);

        fin;
    fin;
    define-nueva-instruccion dup(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            dup(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            repetir n veces
                deja-zumbador;
            g(2);
            avanza;
            g(2);

        fin;
    fin;
    define-nueva-instruccion ord(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            avanza;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                g(2);
                avanza;
                g(2);
                ord(sucede(n));
            fin
            sino
            inicio
                deja-zumbador;
                g(2);
                avanza;
                mientras junto-a-zumbador hacer
                inicio
                    coge-zumbador;
                    g(2);
                    avanza;
                    g(2);
                    deja-zumbador;
                    avanza;
                fin;
                repetir n veces
                    deja-zumbador;
                g(2);
                avanza;
                repetir n veces
                    deja-zumbador;
            fin;
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        avanza;
        avanza;
        g(2);
        ord(0);
        g(2);
        dupa(0);
        res(0);
        g(2);
        dup(0);
        avanza;
        avanza;
        dup(0);
        g(2);
        avanza;
        g(2);
        coge-zumbador;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
            avanza;
            coge-zumbador;
            mult(0);
            g(2);
            avanza;
            avanza;
            g(2);
        fin;

        apagate;
    termina-ejecucion
finalizar-programa
