iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion mueve(beepers) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve(sucede(beepers));
        fin sino inicio
            repetir beepers veces deja-zumbador;
            avanza;
            repetir precede(beepers) veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion comparar(x) como inicio
        repetir x veces inicio
            si junto-a-zumbador entonces coge-zumbador;
        fin;
        si junto-a-zumbador entonces inicio
            repetir x veces deja-zumbador;
            mueve(0);
        fin sino inicio
            gira(2);
            mientras frente-libre hacer avanza;
        fin;
    fin;

    define-nueva-instruccion cuenta(menor) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(menor));
        fin sino inicio
            avanza;
            gira(3);
            mientras junto-a-zumbador y orientado-al-este hacer inicio
                comparar(menor);
            fin;
        fin;
    fin;

    define-nueva-instruccion deja(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            deja(x);
            repetir x veces deja-zumbador;
        fin;
    fin;
    
    define-nueva-instruccion multiplicar(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplicar(sucede(x));
        fin sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                deja(x);
            fin sino inicio
                (*suponiendo que es la ultima multiplicacion*)
                gira(2);
                mientras frente-libre hacer avanza;
                gira(1);
                mientras frente-libre hacer avanza;
                repetir x veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        avanza;
        cuenta(0);
        gira(2);
        mientras junto-a-zumbador hacer multiplicar(0);
    termina-ejecucion
finalizar-programa
