iniciar-programa
define-nueva-instruccion resultado(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        resultado(sucede(x));
    fin
    sino
    inicio
        mientras no orientado-al-sur hacer
            gira-izquierda;
        mientras frente-libre hacer
            avanza;
        repetir x veces
            deja-zumbador;
        apagate;
    fin;
fin;
define-nueva-instruccion checa(x) como
inicio
    si junto-a-zumbador y no si-es-cero(x) entonces
    inicio
        coge-zumbador;
        checa(precede(x));
        si junto-a-zumbador entonces
            deja-zumbador;
    fin
    sino
    inicio
        si si-es-cero(x) entonces
        inicio
            mientras no orientado-al-norte hacer
                gira-izquierda;
            avanza;
            resultado(0);
        fin
        sino
            deja-zumbador;
    fin;
fin;
define-nueva-instruccion regresa(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        regresa(sucede(x));
    fin
    sino
    inicio
        repetir 2 veces
            gira-izquierda;
        mientras frente-libre hacer
            avanza;
        repetir x veces
            deja-zumbador;
        repetir 3 veces
            gira-izquierda;
    fin;
fin;
define-nueva-instruccion multiplica2(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        multiplica2(x);
        repetir x veces
            deja-zumbador;
    fin
    sino
    inicio
        repetir 2 veces
            gira-izquierdA;
    fin;
fin;
define-nueva-instruccion multiplica(x) como
inicio
   si junto-a-zumbador entonces
   inicio
       coge-zumbador;
       multiplica(sucede(x));
   fin
   sino
   inicio
       si frente-libre entonces
       inicio
           avanza;
           si junto-a-zumbador entonces
               multiplica2(x)
           sino
               repetir x veces
                   deja-zumbador;
       fin
       sino
           repetir x veces
               deja-zumbador;

   fin;
fin;

define-nueva-instruccion divide2(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        repetir x veces
            coge-zumbador;
        divide2(x);
        deja-zumbador;
    fin;
fin;
define-nueva-instruccion divide(x) como
inicio
   si junto-a-zumbador entonces
   inicio
       coge-zumbador;
       divide(sucede(x));
   fin
   sino
   inicio
        avanza;
        divide2(x);
        regresa(0);
        apagate;
   fin;
fin;
define-nueva-instruccion expandir(x) como
inicio
    si no si-es-cero(x) entonces
    inicio
       repetir 2 veces
           gira-izquierda;
       avanza;
       gira-izquierda;
       avanza;
       checa(x);
       si junto-a-zumbador entonces
       inicio
           coge-zumbador;
           repetir 2 veces
               gira-izquierda;
           avanza;
           repetir 3 veces
               gira-izquierda;
           avanza;
           repetir 2 veces
               gira-izquierda;
           repetir x veces
               deja-zumbador;
       fin;
       multiplica(0);
       si frente-libre entonces
       inicio
           avanza;
           expandir(precede(x));
       fin;
    fin;
fin;
define-nueva-instruccion contar(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        contar(sucede(x));
    fin
    sino
    inicio
        repetir x veces
            deja-zumbador;
        mientras no orientado-al-este hacer
            gira-izquierda;
        avanza;
        expandir(precede(x));
        repetir 2 veces
            gira-izquierda;
        avanza;
        repetir 2 veces
            gira-izquierda;
        regresa(0);
    fin;

fin;
    inicia-ejecucion
    repetir 2 veces
    inicio
        avanza;
    fin;
        repetir 3 veces
            gira-izquierda;
        contar(0);

        apagate;
    termina-ejecucion
finalizar-programa
