iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion copia (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            copia (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            gira (3);
            avanza;
            repetir n veces
                deja-zumbador;
            gira (2);
            avanza;
            gira (1);
            avanza;
            gira (2);
        fin;
    fin;
    define-nueva-instruccion resta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            resta (sucede(n));
        fin
        sino inicio
            avanza;
            repetir n veces
                coge-zumbador;
        fin;
    fin;
    define-nueva-instruccion proceso (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            proceso (sucede(n));
        fin
        sino inicio
            gira (2);
            avanza;
            gira (1);
            avanza;
            gira (1);
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion pon (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pon (sucede(n));
        fin
        sino inicio
            repetir n veces
                deja-zumbador;
            coge-zumbador;
            gira (2);
            avanza;
            avanza;
            gira (3);
            mientras frente-libre hacer
                avanza;
            gira (2);
            mientras junto-a-zumbador hacer
                avanza;
            repetir n veces
                deja-zumbador;
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (2);
            avanza;
            gira (1);
            avanza;
        fin;
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta (n);
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion multi (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multi (sucede(n));
        fin
        sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                cuenta (n);
                multi (0);
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                repetir n veces
                    deja-zumbador;
                gira (3);
            fin;
        fin;
    fin;
    define-nueva-instruccion karelianos como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
        avanza;
        avanza;
        copia (0);
        resta (0);
        proceso (0);
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            avanza;
            pon (0);
        fin;
        si no-junto-a-zumbador entonces inicio
            avanza;
            mientras junto-a-zumbador hacer
                coge-zumbador;
            gira (2);
            avanza;
            avanza;
            gira (3);
            avanza;
            gira (2);
        fin;
        multi (0);
    fin;
    inicia-ejecucion
        karelianos;
        apagate;
    termina-ejecucion
finalizar-programa