iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
      define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;
      define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
      define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;
    define-nueva-instruccion deja(n) como inicio
        repetir n veces deja-zumbador;
    fin;
    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
    fin;
    define-nueva-instruccion minimo(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            minimo(sucede(n));
        fin sino inicio
            deja(n);
            mientras frente-libre hacer inicio
                repetir n veces inicio
                    si frente-libre entonces avanza;
                fin;
                deja-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion comun como inicio
        mientras no-orientado-al-sur hacer inicio
            mientras no-junto-a-zumbador hacer avanza;
            oeste;
            avanza;
            si junto-a-zumbador entonces inicio
                sur;
            fin sino inicio
                este;
                avanza;
                norte;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta(n) como inicio
        si frente-libre entonces inicio
            avanza;
            cuenta(sucede(n));
        fin sino inicio
            este;
            avanza;
            avanza;
            repetir n veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion torneo como inicio
        minimo(0);
        ir11;
        este;
        avanza;
        norte;
        minimo(0);
        ir11;
        este;
        avanza;
        norte;
        avanza;
        comun;
        cuenta(0);
    fin;
    inicia-ejecucion
        ir11;
        norte;
        torneo;
        apagate;
    termina-ejecucion
finalizar-programa
