iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion orientar como
    inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion torneo(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            torneo(sucede(n));
        fin sino
        inicio
            repetir n veces avanza;
            sur;
            avanza;
            norte;
            deja-zumbador;
            mientras frente-libre hacer
            inicio
                repetir n veces si frente-libre entonces avanza;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar como
    inicio
        si frente-libre entonces
        inicio
            avanza;
            contar;
        fin sino
        inicio
            este;
            repetir 2 veces avanza;
        fin;
        deja-zumbador;
    fin;

    define-nueva-instruccion torneo2(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            torneo2(sucede(n));
        fin sino
        inicio
            orientar;
            repetir n veces avanza;
            sur;
            avanza;
            norte;
            mientras no-junto-a-zumbador hacer repetir n veces si frente-libre entonces avanza
            sino apagate;
            sur;
            contar;
         fin;
     fin;

    inicia-ejecucion
        orientar;
        torneo(0);
        orientar;
        este;
        avanza;
        torneo2(0);
        apagate;
    termina-ejecucion
finalizar-programa
