iniciar-programa
    define-nueva-instruccion orientanorte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;

    define-nueva-instruccion orientasur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;

    define-nueva-instruccion orientaeste como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;

    define-nueva-instruccion orientaoeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;

    define-nueva-instruccion llega11 como inicio
        orientaoeste;
        mientras frente-libre hacer avanza;
        orientasur;
        mientras frente-libre hacer avanza;
        orientanorte;
    fin;

    define-nueva-instruccion multiplo(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            multiplo(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            mientras frente-libre hacer inicio
                repetir x veces si frente-libre entonces avanza;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion llega12 como inicio
        llega11;
        orientaeste;
        avanza;
        orientanorte;
    fin;

    define-nueva-instruccion mcm como inicio
        orientasur;
        si frente-libre entonces inicio
            avanza;
            mcm;
            deja-zumbador;
        fin sino inicio
            llega11;
            orientaeste;
            repetir 2 veces avanza;
            orientanorte;
        fin;
    fin;

    define-nueva-instruccion checa como inicio
        orientanorte;
        mientras frente-libre hacer inicio
            avanzA;
            orientaoeste;
            mientras frente-libre hacer avanza;
            orientaeste;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                avanza;
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    sal-de-instruccion;
                fin;
            fin;
            orientanorte;
        fin;
    fin;

    inicia-ejecucion
        llega11;
        multiplo(0);
        llega12;
        multiplo(0);
        llega11;
        checa;
        mcm;
        apagate;
    termina-ejecucion
finalizar-programa
