iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion extender(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        extender(sucede(a));
    fin sino inicio
        avanza;
        gira(3);
        repetir precede(a) veces avanza;
        deja-zumbador;
        mientras frente-libre hacer inicio
            repetir a veces si frente-libre entonces avanza;
            si no-junto-a-zumbador entonces deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion alinear(b) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        alinear(sucede(b));
    fin sino inicio
        gira(2);
        avanza;
        gira(2);
        repetir precede(b) veces avanza;
        deja-zumbador;
        mientras frente-libre hacer inicio
            repetir b veces si frente-libre entonces avanza;
            deja-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion comparar como inicio
    mientras no-junto-a-zumbador hacer avanza;
    gira(1);
    avanza;
fin;

define-nueva-instruccion multiplo(d) como inicio
    si frente-libre entonces inicio
        avanza;
        multiplo(sucede(d));
    fin sino inicio
        gira(1);
        avanza;
        gira(1);
        repetir 2 veces avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir d veces deja-zumbador;
        deja-zumbador;
        apagate;
    fin;
fin;


    inicia-ejecucion

    mientras no-orientado-al-oeste hacer gira(1);
    mientras frente-libre hacer avanza;
    gira(1);
    mientras frente-libre hacer avanza;
    gira(2);
    extender(0);
    si junto-a-zumbador entonces coge-zumbador;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(1);
    avanza;
    gira(1);
    avanza;
    alinear(0);
    coge-zumbador;
    gira(2);
    mientras frente-libre hacer avanza;
    gira(2);
    mientras no-junto-a-zumbador hacer inicio
        comparar;
        si junto-a-zumbador entonces inicio
            gira(1);
            multiplo(0)
        fin sino inicio
            gira(2);
            avanza;
            gira(1);
            avanza;
        fin;
    fin;

        apagate;
    termina-ejecucion
finalizar-programa
