iniciar-programa
    define-nueva-instruccion g(n) como
        repetir n veces
            gira-izquierda;
    define-nueva-instruccion final(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            final(sucede(n));
        fin
        sino
        inicio
            mientras frente-libre hacer
                avanza;
            g(2);
            repetir 2 veces
                avanza;
            g(3);
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion ord(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            avanza;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                g(2);
                avanza;
                g(2);
                ord(sucede(n));
            fin
            sino
            inicio
                deja-zumbador;
                g(2);
                avanza;
                mientras junto-a-zumbador hacer
                inicio
                    coge-zumbador;
                    g(2);
                    avanza;
                    g(2);
                    deja-zumbador;
                    avanza;
                fin;
                repetir n veces
                    deja-zumbador;
                g(2);
                avanza;
                repetir n veces
                    deja-zumbador;
            fin;
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;

    fin;
    define-nueva-instruccion cop(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            cop(sucede(n));
        fin
        sino
        inicio
            repetir n veces
                deja-zumbador;
            avanza;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion ad(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ad(sucede(n));
        fin
        sino
        inicio
            g(2);
            avanza;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion div(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            div(sucede(n));
        fin
        sino
        inicio
            avanza;
            mientras junto-a-zumbador hacer
            inicio
                repetir n veces
                inicio
                    si junto-a-zumbador entonces
                    inicio
                        coge-zumbador;
                        avanza;
                        deja-zumbador;
                        g(2);
                        avanza;
                        g(2);
                    fin
                    sino
                    inicio
                        avanza;
                        ad(0);
                        g(2);
                        avanza;
                        repetir n veces
                            deja-zumbador;
                        g(2);
                        avanza;
                        g(2);
                        sal-de-instruccion;
                    fin;
                fin;
                avanza;
                si junto-a-zumbador entonces
                inicio
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    g(1);
                    avanza;
                    deja-zumbador;
                    g(2);
                    avanza;
                    g(3);
                    avanza;
                    g(2);
                fin;
            fin;
            repetir n veces
                deja-zumbador;
            g(2);
            avanza;
            g(2);
            sal-de-instruccion;
        fin;
    fin;
    define-nueva-instruccion mult(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            mult(sucede(n));

        fin
        sino
        inicio
            avanza;
            mientras junto-a-zumbador hacer
            inicio
                coge-zumbador;
                avanza;
                repetir n veces
                    deja-zumbador;
                g(2);
                avanza;
                g(2);
            fin;
        fin;
    fin;
    define-nueva-instruccion am(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            am(sucede(n));
        fin
        sino
        inicio
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    inicia-ejecucion
        mientras no-orientado-al-sur hacer
            g(1);
        mientras frente-libre hacer
            avanza;
        g(3);
        mientras frente-libre hacer
            avanza;
        g(2);
        cop(0);
        g(2);
        avanza;
        g(2);
        cop(0);
        g(2);
        avanza;
        g(2);
        mult(0);
        g(2);
        mientras frente-libre hacer
            avanza;
        g(2);
        ord(0);
        g(2);
        avanza;
        g(2);
        mientras junto-a-zumbador hacer
            div(0);
        avanza;
        cop(0);
        div(0);
        avanza;
        avanza;
        g(1);
        avanza;
        g(1);
        final(0);
        apagate;
    termina-ejecucion
finalizar-programa
