iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;

    define-nueva-instruccion orientar como inicio
        sur;
        corre;
        oeste;
        corre;
        norte;
    fin;

    define-nueva-instruccion agregar_num(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            agregar_num(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            avanza;
            repetir x veces deja-zumbador;
            sal-de-instruccion;
        fin;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                oeste;
                avanza;
                este;
                comparar(sucede(n));
            fin sino inicio
                oeste;
                avanza;
                repetir n veces deja-zumbador;
                deja-zumbador;
                este;
                avanza;
                repetir n veces deja-zumbador;
                sur;
                avanza;
                norte;
                agregar_num(0);
                oeste;
                avanza;
                este;
            fin;
        fin sino inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                sur;
                avanza;
                este;
                avanza;
                repetir n veces deja-zumbador;
                apagate;
            fin sino inicio
                repetir n veces deja-zumbador;
                oeste;
                avanza;
                repetir n veces deja-zumbador;
                sur;
                avanza;
                norte;
                agregar_num(0);
                este;
            fin;
        fin;
    fin;

    inicia-ejecucion
        orientar;
        agregar_num(0);
        sur;
        avanza;
        este;
        avanza;
        norte;
        agregar_num(0);
        oeste;
        avanza;
        este;
        mientras frente-libre hacer inicio
            comparar(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
