iniciar-programa
define-nueva-instruccion avanzar(n) como si si-es-cero(n) entonces mientras frente-libre hacer avanza sino repetir n veces si frente-libre entonces avanza;
define-nueva-instruccion dejar(n) como si si-es-cero(n) entonces mientras algun-zumbador-en-la-mochila hacer deja-zumbador sino repetir n veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
define-nueva-instruccion coger(n) como si si-es-cero(n) entonces mientras junto-a-zumbador hacer coge-zumbador sino repetir n veces si junto-a-zumbador entonces coge-zumbador;
define-nueva-instruccion girar(n) como repetir n veces gira-izquierda;
define-nueva-instruccion al-norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion al-sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion al-este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion al-oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion copiar(n) como inicio
    si junto-a-zumbador entonces inicio
        coger(1);
        copiar(sucede(n));
    fin sino inicio
        si no si-es-cero(n) entonces dejar(n);
        avanzar(1);
        si no si-es-cero(n) entonces dejar(n);
    fin;
fin;
define-nueva-instruccion modulo(n) como inicio
    si si-es-cero(n) y no-junto-a-zumbador entonces inicio
        al-norte;
        avanzar(1);
        al-este;
        copiar(0);
        al-sur;
        copiar(0);
        apagate;
    fin sino si no si-es-cero(n) y junto-a-zumbador entonces inicio
        coger(1);
        modulo(precede(n));
    fin;
fin;
define-nueva-instruccion probar(n) como inicio
    si junto-a-zumbador entonces inicio
        coger(1);
        probar(sucede(n));
    fin sino inicio
        si no si-es-cero(n) entonces dejar(n);
        avanzar(1);
        al-norte;
        avanzar(1);
        coger(0);
        al-sur;
        avanzar(1);
        al-norte;
        copiar(0);
        al-sur;
        avanzar(1);
        mientras junto-a-zumbador hacer modulo(n);
        coger(0);
        al-norte;
        avanzar(1);
        al-sur;
        copiar(0);
        al-oeste;
        avanzar(1);
        al-este;
    fin;
fin;
define-nueva-instruccion contar(n) como inicio
    si junto-a-zumbador entonces inicio
        coger(1);
        contar(sucede(n));
    fin sino inicio
        mientras frente-libre o frente-bloqueado hacer inicio
            dejar(n);
            al-oeste;
            avanzar(0);
            al-este;
            probar(0);
            al-este;
            avanzar(1);
        fin;
    fin;
fin;
    inicia-ejecucion
        al-oeste; avanzar(0);
        al-sur; avanzar(0);
        al-este;
        avanzar(1);
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
