iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion verifica como inicio
        oeste;
        mientras frente-libre hacer avanza;
        este;
        si frente-libre entonces inicio
            mientras derecha-bloqueada y frente-libre hacer avanza;
            si derecha-libre entonces inicio
                sur;
            fin;
        fin sino inicio
            si frente-bloqueado y derecha-libre entonces sur;
        fin;
    fin;
    define-nueva-instruccion baja(n) como inicio
        verifica;
        si izquierda-bloqueada y derecha-bloqueada y frente-libre entonces inicio
            avanza;
            baja(sucede(n));
        fin sino inicio
            si frente-bloqueado y derecha-bloqueada entonces inicio
                oeste;
                mientras frente-libre hacer avanza;
                repetir n veces deja-zumbador;
                apagate;
            fin;
            si frente-libre entonces avanza;
            baja(n);
        fin;
    fin;
    inicia-ejecucion
        baja(0);
        apagate;
    termina-ejecucion
finalizar-programa
