iniciar-programa

define-nueva-instruccion gira(g) como inicio
repetir g veces gira-izquierda;
fin;

define-nueva-instruccion suma como inicio
    si junto-a-zumbador entonces inicio
    coge-zumbador;
    suma;
    deja-zumbador;
    fin sino inicio
    gira(3);
    avanza;
    fin;
fin;

define-nueva-instruccion base(k) como inicio
    si junto-a-zumbador entonces inicio
    coge-zumbador;
    base(sucede(k));
    fin sino inicio
    gira(2);
    avanza;
    gira(1);
    avanza;
        repetir 11 veces inicio
        repetir k veces deja-zumbador;
        avanza;
        fin;
    fin;
fin;

define-nueva-instruccion compara(n) como inicio
    si no si-es-cero (n) y junto-a-zumbador entonces inicio
    coge-zumbador;
    compara(precede(n));
    fin sino inicio

        si si-es-cero (n) y no-junto-a-zumbador entonces inicio
            si orientado-al-norte entonces inicio
            gira(2);
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            gira(3);
            avanza;
            gira(3);
            deja-zumbador;
            gira(1);
            fin;
        fin;

        si si-es-cero (n) y junto-a-zumbador entonces inicio
            si orientado-al-norte entonces inicio
            gira(1);
            avanza;
            gira(1);
            avanza;
            gira(2);
            fin;
        fin;

        si no si-es-cero (n) y no-junto-a-zumbador entonces inicio
        gira(2);
        avanza;
        mientras junto-a-zumbador hacer coge-zumbador;
        repetir n veces deja-zumbador;
        gira(3);
        avanza;
        deja-zumbador;
        gira(3);
        fin;

    fin;
fin;

define-nueva-instruccion glup(n) como inicio
    si junto-a-zumbador entonces inicio
    coge-zumbador;
    glup(sucede(n));
    fin sino inicio
    repetir n veces deja-zumbador;
    avanza;
    compara(n);
    fin;
fin;

define-nueva-instruccion acomoda como inicio
    si junto-a-zumbador entonces inicio
    coge-zumbador;
    acomoda;
    deja-zumbador;
    fin sino inicio
    avanza;
    fin;
fin;

    inicia-ejecucion

    repetir 2 veces avanza;
    gira(3);
    avanza;
        repetir 11 veces inicio
            si junto-a-zumbador entonces inicio
            suma;
            gira(2);
            avanza;
            gira(3);
            avanza;
            fin sino inicio
            avanza;
            fin;
        fin;
    gira(2);
    repetir 12 veces avanza;
    gira(3);
    avanza;
    base(0);

    gira(3);
    avanza;
    gira(3);
    avanza;
    gira(3);
        repetir 11 veces inicio
            si junto-a-zumbador entonces inicio
            glup(0);
            mientras no-orientado-al-norte hacer gira-izquierda;
            fin sino inicio
            gira(1);
            avanza;
            gira(3);
            fin;
        fin;

    gira(2);
        repetir 12 veces inicio
            si junto-a-zumbador entonces inicio
            acomoda;
            gira(2);
            avanza;
            gira(3);
            avanza;
            gira(3);
            fin sino inicio
            gira(1);
            avanza;
            gira(3);
            fin;
        fin;

        apagate;
    termina-ejecucion
finalizar-programa
