iniciar-programa
define-nueva-instruccion gira(q) como repetir q veces gira-izquierda;
define-nueva-instruccion juntar como inicio
    si junto-a-zumbador y frente-libre y orientado-al-sur entonces inicio
        coge-zumbador;
        juntar;
        deja-zumbador;
    fin sino inicio
        si frente-libre entonces avanza;
        si frente-libre entonces juntar;
    fin;
fin;
define-nueva-instruccion suma(x) como inicio
    repetir x veces inicio
        si junto-a-zumbador y orientado-al-oeste entonces inicio
            coge-zumbador;
        fin sino inicio
            mientras no orientado-al-norte hacer gira(1);
            deja-zumbador;
        fin;
    fin;
    si orientado-al-oeste entonces inicio
        si frente-libre entonces avanza;
        deja-zumbador;
        mientras no orientado-al-este hacer gira(1);
        si frente-libre entonces avanza;
        mientras no orientado-al-oeste hacer gira(1);
        suma(x);
    fin sino inicio
        repetir x veces inicio
            si junto-a-zumbador y orientado-al-norte entonces inicio
                coge-zumbador;
            fin sino inicio
                mientras no orientado-al-oeste hacer gira(1);
                deja-zumbador;
            fin;
        fin;
        mientras no orientado-al-oeste hacer gira(1);
    fin;
fin;
define-nueva-instruccion base(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        base(sucede(x));
    fin sino inicio
        mientras no orientado-al-sur hacer gira(1);
        mientras frente-libre hacer avanza;
        mientras no orientado-al-este hacer gira(1);
        repetir 11 veces avanza;
        mientras no orientado-al-norte hacer gira(1);
        mientras frente-libre hacer inicio
            repetir 2 veces avanza;
            mientras no orientado-al-sur hacer gira(1);
            juntar;
            mientras no orientado-al-oeste hacer gira(1);
            si junto-a-zumbador entonces suma(x);
            si frente-libre entonces avanza;
            si frente-libre entonces gira(3);
        fin;
    fin;
fin;
    inicia-ejecucion
    si frente-libre entonces repetir 3 veces avanza;
    base(0);
        apagate;
    termina-ejecucion
finalizar-programa
