iniciar-programa
    define-nueva-instruccion norte como  mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ubicar como inicio
        este;
        repetir 11 veces inicio
            avanza;
        fin;
        norte;
        avanza;
        avanza;
        sur;
    fin;
    define-nueva-instruccion contar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar;
            deja-zumbador;
        fin sino inicio
            sur;
            avanza;
        fin;
    fin;
    define-nueva-instruccion juntar como inicio
        repetir 2 veces inicio
            contar;
        fin;
        oeste;
        avanza;
        norte;
        avanza;
        avanza;
        sur;
    fin;

    define-nueva-instruccion restar(n) como inicio
        si no si-es-cero(n) y junto-a-zumbador entonces inicio
            coge-zumbador;
            restar(precede(n));
        fin sino inicio
            si si-es-cero(n) entonces inicio
                oeste;
                avanza;
                deja-zumbador;
                este;
                avanza;
            fin;
            si no junto-a-zumbador y no si-es-cero(n) entonces inicio
                norte;
                avanza;
                repetir n veces inicio
                    coge-zumbador;
                fin;
                contar;
                oeste;
                avanza;
                norte;
                avanza;
            fin;
            si si-es-cero(n) y no junto-a-zumbador entonces inicio
                norte;
                avanza;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                oeste;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion sumar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            sumar(sucede(n));
        fin sino inicio
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
            repetir 11 veces inicio
                avanza;
            fin;
            norte;
            avanza;
            repetir 11 veces inicio
                repetir n veces inicio
                    deja-zumbador;
                fin;
                sur;
                avanza;
                si no junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    mientras junto-a-zumbador hacer inicio
                        coge-zumbador;
                    fin;
                    oeste;
                    avanza;
                fin;
                mientras junto-a-zumbador hacer inicio
                    restar(n);
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ubicar;
        repetir 11 veces inicio
            juntar;
        fin;
        norte;
        avanza;
        sumar(0);
        apagate;
    termina-ejecucion
finalizar-programa
