iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion acomodar como inicio
        si frente-libre entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                acomodar;
                deja-zumbador;
            fin sino inicio
                avanza;
                acomodar;
            fin;
        fin;
    fin;

    define-nueva-instruccion checar(base) como inicio
        si no-junto-a-zumbador entonces inicio
            si si-es-cero(base) entonces inicio
                avanza;
                deja-zumbador;
                gira(2);
                avanza;
                gira(2);
                gira(1);
            fin;
        fin sino inicio
            si si-es-cero(base) entonces inicio
                avanza;
                deja-zumbador;
                gira(2);
                avanza;
                gira(2);
                gira(1);
            fin sino inicio
                coge-zumbador;
                checar(precede(base));
                si orientado-al-oeste entonces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(base) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(base));
        fin sino inicio
            repetir 11 veces inicio
                gira(3);
                avanza;
                gira(3);
                acomodar;
                gira(2);
                repetir 3 veces avanza;
            fin;
            gira(2);
            repetir 3 veces avanza;
            gira(3);
            repetir 11 veces inicio
                checar(base);
                mientras no-orientado-al-oeste hacer gira-izquierda;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        repetir 3 veces avanza;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
