iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion baja(x) como
    inicio
        si (junto-a-zumbador y frente-libre) entonces
        inicio
            coge-zumbador;
            baja(sucede(x));
        fin
        sino
        inicio
            si frente-libre entonces
            inicio
               avanza;
               baja(x);
            fin
            sino
            inicio
                repetir x veces
                inicio
                    deja-zumbador;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion tirar como
    inicio
        repetir 11 veces
        inicio
            avanza;
            sur;
            baja(0);
            norte;
            avanza;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion principio como
    inicio
        norte;
        avanza;
        avanza;
        este;
        tirar;
        norte;
        avanza;
        oeste;
        camina;
        este;
    fin;

    define-nueva-instruccion sumar(x) como
    inicio
        si (junto-a-zumbador y orientado-al-oeste) entonces
        inicio
            repetir x veces
            inicio
                si junto-a-zumbador entonces
                inicio
                   coge-zumbador;
                fin
                sino
                inicio
                    norte;
                    repetir precede(x) veces
                    inicio
                        deja-zumbador;
                    fin;
                fin;
            fin;
            si ((junto-a-zumbador y orientado-al-oeste) o no-junto-a-zumbador) entonces
            inicio
                avanza;
                deja-zumbador;
                este;
                avanza;
                oeste;
            fin;
        fin
        sino
        inicio
            oeste;
            si frente-libre entonces
            inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           contar(sucede(x));
        fin
        sino
        inicio
            sur;
            camina;
            este;
            repetir 11 veces
            inicio
                avanza;
            fin;
            oeste;
            mientras frente-libre hacer
            inicio
                sumar(x);
            fin;
        fin;
    fin;

    inicia-ejecucion
        principio;
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
