iniciar-programa
   define-nueva-instruccion gira(n) como
   inicio
      repetir n veces
         gira-izquierda;
   fin;
   define-nueva-instruccion suma como
   inicio
      si junto-a-zumbador entonces
      inicio
         coge-zumbador;
         suma;
         deja-zumbador;
      fin
      sino
      inicio
         gira(2);
         mientras frente-libre hacer
            avanza;
      fin;
   fin;
   define-nueva-instruccion cuenta(n) como
   inicio
      si junto-a-zumbador y no si-es-cero(n) entonces
      inicio
         coge-zumbador;
         avanza;
         deja-zumbador;
         gira(2);
         avanza;
         gira(2);
         cuenta(precede(n));
      fin       
      sino
         si si-es-cero(n) entonces
         inicio
            gira-izquierda;
            avanza;
            deja-zumbador;
            gira(2);
            avanza;
            gira-izquierda;
         fin
         sino
         inicio
            avanza;
            suma;
            gira(2);
         fin;
   fin;
   define-nueva-instruccion base(n) como
   inicio
      si junto-a-zumbador entonces
      inicio
         coge-zumbador;
         base(sucede(n));
      fin
      sino
      inicio
         gira(2);
         mientras frente-libre hacer
            avanza;
         gira-izquierda;
         repetir 11 veces
            avanza;
         gira-izquierda;
         repetir 11 veces
         inicio
            cuenta(n);
            gira-izquierda;
            avanza;
            gira(3);
         fin;
      fin;
   fin;

    inicia-ejecucion
       gira(3);
       avanza;
       gira-izquierda;
       repetir 11 veces
       inicio
          avanza;
          suma;
          gira(2);
          repetir 2 veces
             avanza;
          suma;
          gira-izquierda;
          avanza;
          gira-izquierda;
       fin;
       gira-izquierda;
       mientras frente-libre hacer
         avanza;
       gira(3);
       repetir 3 veces
          avanza;
       base(0);
        apagate;
    termina-ejecucion
finalizar-programa
