iniciar-programa

    define-nueva-instruccion gira-derecha como inicio
        gira-izquierda;
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion media-vuelta como inicio
        gira-izquierda;
        gira-izquierda;
    fin;

    define-nueva-instruccion orienta como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        repetir 11 veces avanza;
        gira-izquierda;
    fin;

    define-nueva-instruccion deja como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        media-vuelta;
    fin;

    define-nueva-instruccion suma(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            suma(sucede(n));
        fin
        sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                suma(n);
            fin
            sino inicio
                si frente-libre entonces avanza;
                si junto-a-zumbador entonces inicio
                    suma(n);
                fin
                sino inicio
                    deja;
                    repetir n veces deja-zumbador;
                    si izquierda-libre entonces inicio
                        gira-izquierda;
                        avanza;
                        gira-derecha;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion resta(n) como inicio
        si orientado-al-norte entonces inicio
            repetir n veces inicio
                si junto-a-zumbador y orientado-al-norte entonces inicio
                    coge-zumbador;
                fin
                sino inicio
                    mientras no-orientado-al-sur hacer gira-izquierda;
                    deja-zumbador;
                fin;
            fin;
        fin;
        si no-junto-a-zumbador y orientado-al-norte entonces inicio
            gira-izquierda;
            avanza;
            deja-zumbador;
            gira-derecha;
        fin
        sino inicio
            si junto-a-zumbador y orientado-al-norte entonces inicio
                gira-izquierda;
                avanza;
                deja-zumbador;
                gira-derecha;
            fin;
        fin;
        si orientado-al-sur entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                resta(n);
                coge-zumbador;
            fin
            sino inicio
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion base(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            base(sucede(n));
        fin
        sino inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer avanza;
            orienta;
            mientras izquierda-libre hacer inicio
                si orientado-al-sur entonces inicio
                    gira-derecha;
                    avanza;
                    gira-derecha;
                fin;
                si junto-a-zumbador entonces inicio
                    resta(n);
                fin
                sino inicio
                    si izquierda-libre entonces inicio
                        gira-izquierda;
                        avanza;
                        gira-derecha;
                    fin;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        orienta;
        mientras izquierda-libre hacer suma(0);
        repetir 3 veces avanza;
        base(0);
        apagate;
    termina-ejecucion
finalizar-programa
