iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion camina como
    inicio
    si frente-libre entonces avanza
    sino
        inicio
        si orientado-al-norte entonces
            inicio
                este;
            si frente-libre entonces
                inicio
                    avanza;
                    sur;
                fin;
            fin
        sino
            inicio
                este;
            si frente-libre entonces
                inicio
                    avanza;
                    norte;
                fin;
            fin;
        fin;
    fin;

define-nueva-instruccion ve1-1 como
    inicio
        sur;
    mientras frente-libre hacer avanza;
        oeste;
    mientras frente-libre hacer avanza;
        este;
    fin;

define-nueva-instruccion junta como
    inicio
        norte;
    mientras no-orientado-al-este hacer
        inicio
        mientras junto-a-zumbador hacer coge-zumbador;
            camina;
        fin;
    fin;

define-nueva-instruccion piso(x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            piso(sucede(x));
        fin
    sino
        inicio
            repetir x veces deja-zumbador;
            avanza;
            repetir sucede(sucede(x)) veces deja-zumbador;
        fin;
    fin;

define-nueva-instruccion reacomoda(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            reacomoda(sucede(n));
        fin
    sino
        inicio
        si frente-libre entonces avanza;
        si junto-a-zumbador entonces
            inicio
                reacomoda(0);
            fin
        sino
            inicio
                oeste;
            mientras frente-libre hacer avanza;
                norte;
            fin;
        fin;
    si si-es-cero (n) entonces avanza sino deja-zumbador;
    fin;

define-nueva-instruccion haz(c) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            haz(sucede(c));
        fin
    sino
        inicio
            sur;
        si frente-libre entonces
            inicio
                avanza;
                este;
            mientras no-junto-a-zumbador hacer avanza;
                norte;
                avanza;
                este;
                avanza;
            repetir c veces
                inicio
                    deja-zumbador;
                    avanza;
                fin;
                oeste;
            mientras frente-libre hacer avanza;
                norte;
                avanza;
            fin
        sino
            inicio
               este;
            repetir c veces
                inicio
                    deja-zumbador;
                    avanza;
                fin;
                oeste;
            mientras frente-libre hacer avanza;
                norte;
                avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        junta;
        ve1-1;
        si algun-zumbador-en-la-mochila entonces deja-zumbador;
        mientras algun-zumbador-en-la-mochila hacer piso(0);
            oeste;
        mientras frente-libre hacer avanza;
            este;
        si junto-a-zumbador entonces reacomoda(0);
        ve1-1;
        mientras junto-a-zumbador hacer haz(0);
        sur;
        avanza;
        este;
        mientras no-junto-a-zumbador hacer avanza;
        norte;
        apagate;
    termina-ejecucion
finalizar-programa
