iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion sube como
    inicio
        norte;
        avanza;
        oeste;
        avanza;
    fin;

    define-nueva-instruccion construye(n) como
    inicio
        si algun-zumbador-en-la-mochila entonces
        inicio
            repetir 2 veces si algun-zumbador-en-la-mochila entonces
            inicio
                repetir n veces
                 inicio
                    si no-junto-a-zumbador entonces deja-zumbador;
                    si no si-es-cero(precede(n)) entonces sube;
                 fin;
                 sur;
                 mientras frente-libre hacer avanza;
                 este;
                 repetir sucede(n) veces avanza;
            fin;
            construye(sucede(n));
         fin;
    fin;

    define-nueva-instruccion punta como
    inicio
        este;
        mientras junto-a-zumbador hacer avanza;
        oeste;
        avanza;
        mientras junto-a-zumbador hacer sube;
        este;
        avanza;
        sur;
        avanza;
        norte;
    fin;

    inicia-ejecucion
        este;
        si no-junto-a-zumbador entonces deja-zumbador;
        avanza;
        si no-junto-a-zumbador entonces deja-zumbador;
        avanza;
        construye(2);
        punta;
        apagate;
    termina-ejecucion
finalizar-programa
