iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion gira-derecha como inicio
        repetir 3 veces inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        si frente-libre entonces inicio
            avanza;
            regresa;
            avanza;
        fin
        sino inicio
            gira-izquierda;
        fin;
    fin;
    define-nueva-instruccion bloque como inicio
        si no-junto-a-zumbador y algun-zumbador-en-la-mochila entonces inicio
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion checa como inicio
        bloque;
        gira-izquierda;
        avanza;
        bloque;
        gira-derecha;
        avanza;
        bloque;
    fin;
    define-nueva-instruccion rellena(n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            gira-izquierda;
            gira-izquierda;
            regresa;
            avanza;
            avanza;
            gira-izquierda;
            repetir n veces inicio
                checa;
            fin;
            rellena(sucede(n));
        fin
        sino inicio
            mientras junto-a-zumbador hacer inicio
                gira-derecha;
                avanza;
                gira-izquierda;
                avanza;
            fin;
            gira-izquierda;
            avanza;
            gira-izquierda;
            avanza;
            norte;
        fin;
    fin;
    inicia-ejecucion
        norte;
        bloque;
        rellena(1);
        apagate;
    termina-ejecucion
finalizar-programa
