iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
    define-nueva-instruccion acomoda como  inicio
        oeste;
        avanzar;
        sur;
        avanzar;
        este;
    fin;
    define-nueva-instruccion piramide(x) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            repetir 2 veces inicio
                repetir x veces avanza;
            fin;
            repetir 2 veces gira-izquierda;
            si no-junto-a-zumbador entonces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                repetir x veces inicio
                    si no-junto-a-zumbador entonces deja-zumbador;
                    norte;
                    avanza;
                    si no-junto-a-zumbador entonces deja-zumbador;
                    oeste;
                    avanza;
                fin;
            fin;
            acomoda;
            piramide(sucede(x));
        fin;
    fin;
    define-nueva-instruccion mitad como inicio
        si junto-a-zumbador entonces inicio
            avanza;
            avanza;
            mitad;
            avanza;
        fin sino inicio
            repetir 2 veces gira-izquierda;
            avanza;
        fin;
    fin;
    inicia-ejecucion
        acomoda;
        piramide(0);
        mitad;
        norte;
        mientras junto-a-zumbador hacer avanza;
        repetir 2 veces gira-izquierda;
        avanza;
        apagate;
    termina-ejecucion
finalizar-programa
