iniciar-programa
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
    fin;
    define-nueva-instruccion avanzas como inicio
        mientras frente-libre hacer inicio
            avanza;
        fin;
    fin;
    define-nueva-instruccion pon como inicio
        oeste;
        avanzas;
        sur;
        avanzas;
    fin;
    define-nueva-instruccion piramide(n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            este;
            repetir n veces inicio
                avanza;
                avanza;
            fin;
            repetir n veces inicio
                oeste;
                si no junto-a-zumbador entonces deja-zumbador;
                avanza;
                si no junto-a-zumbador entonces deja-zumbador;
                norte;
                avanza;
                si no junto-a-zumbador entonces deja-zumbador;
            fin;
            pon;
            piramide(sucede(n))
        fin;
    fin;
    define-nueva-instruccion acomoda como inicio
        este;
        si junto-a-zumbador entonces  inicio
            avanza;
            avanza;
            acomoda;
        fin;
        oeste;
        avanza;
    fin;
    inicia-ejecucion
        si no junto-a-zumbador entonces deja-zumbador;
        piramide(1);
        pon;
        acomoda;
        norte;
        mientras junto-a-zumbador hacer avanza;
        sur;
        avanza;
        apagate;
    termina-ejecucion
finalizar-programa
