iniciar-programa

    define-nueva-instruccion gira(n) como inicio
        repetir n veces gira-izquierda;
    fin;

    define-nueva-instruccion llega11 como inicio
        mientras no-orientado-al-sur hacer gira(1);
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-oeste hacer gira(1);
        mientras frente-libre hacer avanza;
    fin;

    define-nueva-instruccion llena como inicio
        si no-junto-a-zumbador entonces deja-zumbador;
    fin;

    define-nueva-instruccion doble como inicio
        repetir 2 veces inicio
            avanza;
            llena;
        fin;
    fin;

    define-nueva-instruccion l como inicio
        mientras no-orientado-al-oeste hacer gira(1);
        avanza;
        llena;
        gira(3);
        avanza;
        llena;
    fin;

    define-nueva-instruccion piramide(x) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
                mientras no-orientado-al-este hacer gira(1);
                repetir x veces doble;
                repetir x veces l;
                si algun-zumbador-en-la-mochila entonces llega11;
            piramide (sucede(x));
        fin;
    fin;

    define-nueva-instruccion final como inicio
        mientras junto-a-zumbador hacer inicio
            gira(1);
            avanza;
            gira(3);
            avanza;
        fin;
            gira(2);
            avanza;
            gira(1);
            avanza;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-este hacer gira(1);
        si ningun-zumbador-en-la-mochila entonces inicio
            final;
        fin sino inicio
            llena;
            piramide(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa