iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
    define-nueva-instruccion final(k) como inicio
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces avanza;
            final(sucede(k));
            avanza;
            fin
            sino inicio
            gira(3);
            repetir k veces avanza;                    
            gira(3);
            fin;
        fin;
    define-nueva-instruccion punta(i) como inicio
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces avanza;
            punta(sucede(i));
            avanza;
            fin
            sino inicio
            gira(3);
            repetir i veces si frente-libre entonces avanza;
            gira(3);
            fin;
        fin;
    define-nueva-instruccion piramide(x) como inicio
        mientras algun-zumbador-en-la-mochila hacer inicio
            mientras no-orientado-al-sur hacer gira-izquierda;
            mientras frente-libre hacer inicio
                si no-junto-a-zumbador entonces repetir x veces deja-zumbador;
                avanza;
                si no-junto-a-zumbador entonces repetir x veces deja-zumbador;
                gira(1);
                avanza;
                gira(3);
                fin;
            si no-junto-a-zumbador entonces repetir x veces deja-zumbador;
            gira(1);
            si frente-libre entonces avanza;
            mientras no-orientado-al-oeste hacer gira(1);
            punta(0);                                                              
            fin;
        si ningun-zumbador-en-la-mochila entonces inicio
            mientras no-orientado-al-oeste hacer gira(1);
            mientras frente-libre hacer avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(1);
            mientras junto-a-zumbador y frente-libre hacer avanza;
            gira(2);
            si no-junto-a-zumbador entonces avanza;
            final(0);
            apagate;
            fin;
        fin;
    define-nueva-instruccion cuenta(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(x));
            fin;
        si no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(1);
            mientras frente-libre hacer avanza;
            gira(2);
            piramide(x);
            fin;
        fin;
    define-nueva-instruccion busca como inicio
        mientras no-orientado-al-este hacer gira-izquierda;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            cuenta(0);
            fin;
        si frente-bloqueado y no-junto-a-zumbador entonces inicio
            gira(2);
            mientras frente-libre hacer avanza;
            gira(3);
            si frente-bloqueado entonces inicio
                gira(2);
                mientras frente-libre hacer avanza;
                si algun-zumbador-en-la-mochila entonces piramide(1);
                fin;
            si frente-libre entonces inicio
                avanza;
                gira(3);
                busca;
                fin;
            fin;
        fin;
    inicia-ejecucion
        busca;
        apagate;
    termina-ejecucion
finalizar-programa
