iniciar-programa

    define-nueva-instruccion orientar-al-este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion recoger como
    inicio
        repetir 13 veces
        inicio
            repetir 25 veces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    avanza;
                fin
                sino
                inicio
                    avanza;
                fin;
            fin;
            gira-doble;
            camina;
            gira-derecha;
            avanza;
            gira-derecha;
        fin;
    fin;

    define-nueva-instruccion orientar-al-sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion volver-a-k como
    inicio
        orientar-al-sur;
        camina;
        gira-derecha;
        camina;
        gira-doble;
    fin;

    define-nueva-instruccion dejar(x) como
    inicio
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            avanza;
            dejar(sucede(sucede(x)));
        fin;
    fin;

    define-nueva-instruccion ord como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ord;
            deja-zumbador;
        fin
        sino
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion ordenar(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ordenar(sucede(n));
        fin
        sino
        inicio
            repetir n veces
            inicio
                deja-zumbador;
            fin;
            si frente-libre entonces
            inicio
                avanza;
            fin;
            repetir n veces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                fin;
            fin;
            si junto-a-zumbador entonces
            inicio
                mientras algun-zumbador-en-la-mochila hacer
                inicio
                    deja-zumbador;
                fin;
            fin
            sino
            inicio
                gira-doble;
                avanza;
                gira-doble;
                ord;
                gira-doble;
                avanza;
                gira-doble;
                mientras algun-zumbador-en-la-mochila hacer
                inicio
                    deja-zumbador;
                fin;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion jumiles como
    inicio
        volver-a-k;
        gira-izquierda;
        avanza;
        mientras (no-junto-a-zumbador y frente-libre) hacer
        inicio
            avanza;
        fin;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
        fin;
        gira-derecha;
        si derecha-bloqueada entonces
        inicio
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
            avanza;
        fin;
        fin
        sino
        inicio
            gira-derecha;
            si frente-libre entonces
            inicio
            avanza;
            fin;
            gira-izquierda;
            mientras (no-junto-a-zumbador y frente-libre) hacer
            inicio
                si frente-libre entonces
                inicio
                avanza;
                fin;
            fin;
            si frente-libre entonces
            inicio
            avanza;
            fin;
            gira-izquierda;
            si frente-libre entonces
            inicio
            avanza;
            fin;
            gira-derecha;
            mientras algun-zumbador-en-la-mochila hacer
            inicio
                deja-zumbador;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion parche como
    inicio
        si ningun-zumbador-en-la-mochila entonces
        inicio
            si junto-a-zumbador entonces
            inicio
            mientras junto-a-zumbador hacer
            inicio
                avanza;
                gira-izquierda;
                avanza;
                gira-derecha;
            fin;
            gira-derecha;
            avanza;
            gira-derecha;
            avanza;
            fin;
            apagate;
        fin;
    fin;

    inicia-ejecucion
        orientar-al-este;
        parche;
        recoger;
        volver-a-k;
        gira-izquierda;
        dejar(1);
        repetir 25 veces
        inicio
            gira-doble;
            mientras frente-libre hacer
            inicio
                ordenar(0);
            fin;
            gira-doble;
            mientras junto-a-zumbador hacer
            inicio
                avanza;
            fin;
            gira-doble;
            avanza;
            gira-doble;
        fin;
        volver-a-k;
        mientras junto-a-zumbador hacer
        inicio
            coge-zumbador;
        fin;
        mientras algun-zumbador-en-la-mochila hacer
        inicio
            deja-zumbador;
            avanza;
        fin;
        repetir 18 veces
        inicio
        jumiles;
        si frente-bloqueado entonces
        inicio
            volver-a-k;
            mientras junto-a-zumbador hacer
            inicio
                avanza;
                gira-izquierda;
                avanza;
                gira-derecha;
            fin;
            gira-derecha;
            avanza;
            gira-derecha;
            avanza;
            apagate;
        fin;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
