iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion recolecta como inicio
        mientras frente-libre hacer inicio
            si junto-a-zumbador entonces
                coge-zumbador;
            si frente-libre entonces
                avanza;
        fin;
        este;
        si izquierda-libre entonces inicio
            norte;
            avanza;
            si izquierda-bloqueada entonces
                este;
            si derecha-bloqueada entonces
                oeste;
            recolecta;
        fin
        sino inicio
            sur;
            mientras frente-libre hacer
                avanza;
            oeste;
            mientras frente-libre hacer
                avanza;
            este;
        fin;
    fin;
    define-nueva-instruccion reparto (n) como inicio
        si algun-zumbador-en-la-mochila entonces inicio
            repetir n veces
                deja-zumbador;
            si frente-libre entonces
                avanza;
            reparto (sucede(sucede(n)));
        fin;
    fin;
    define-nueva-instruccion cuenta como inicio
        si junto-a-zumbador entonces inicio
            avanza;
            si junto-a-zumbador entonces inicio
                avanza;
                cuenta;
                avanza;
            fin
            sino inicio
                gira (2);
            fin;
        fin
        sino inicio
            gira (2);
        fin;
    fin;
    define-nueva-instruccion punta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        este;
        cuenta;
    fin;
    define-nueva-instruccion construccion (n) como inicio
        norte;
        mientras frente-libre hacer
            avanza;
        sur;
        si no-junto-a-zumbador entonces inicio
            punta;
            avanza;
            norte;
            mientras junto-a-zumbador hacer
                avanza;
            sur;
            avanza;
            apagate;
        fin;
        mientras junto-a-zumbador hacer
            avanza;
        norte;
        avanza;
        sur;
        mientras junto-a-zumbador hacer
            coge-zumbador;
        mientras frente-libre hacer
            avanza;
        norte;
        repetir n veces
            avanza;
        este;
        repetir n veces
            avanza;
        mientras algun-zumbador-en-la-mochila hacer inicio
            deja-zumbador;
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer
            avanza;
        construccion (sucede(n));
    fin;
    inicia-ejecucion
        este;
        recolecta;
        norte;
        mientras frente-libre hacer
            avanza;
        sur;
        reparto (1);
        mientras frente-libre hacer
            avanza;
        construccion (0);
        apagate;
    termina-ejecucion
finalizar-programa