iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion vuelta como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                si junto-a-zumbador entonces
                inicio
                    mientras junto-a-zumbador hacer coge-zumbador;
                fin sino repetir 3 veces gira-izquierda;
            fin sino gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            vuelta;
            repetir n veces avanza;
            camina(n);
        fin;
        deja-zumbador;
    fin;

    define-nueva-instruccion pasos(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            pasos(sucede(n));
         fin sino
         inicio
             repetir n veces avanza;
             camina(n);
         fin;
    fin;

    inicia-ejecucion
        pasos(0);
        apagate;
    termina-ejecucion
finalizar-programa
