iniciar-programa
define-nueva-instruccion norte como inicio
    mientras no-orientado-al-norte hacer gira-izquierda;
fin;
define-nueva-instruccion sur como inicio
    mientras no-orientado-al-sur hacer gira-izquierda;
fin;
define-nueva-instruccion este como inicio
    mientras no-orientado-al-este hacer gira-izquierda;
fin;
define-nueva-instruccion oeste como inicio
    mientras no-orientado-al-oeste hacer gira-izquierda;
fin;

define-nueva-instruccion ir-1-1 como inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
fin;

define-nueva-instruccion paso como inicio
    si frente-bloqueado entonces inicio
        gira-izquierda;
    fin;
    avanza;
fin;

define-nueva-instruccion camina como inicio
    paso;
    mientras no junto-a-zumbador hacer inicio
        paso;
    fin;
fin;

define-nueva-instruccion tachar como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        tachar;
        camina;
    fin;
fin;

define-nueva-instruccion contar-los-zumbadores (n) como inicio
    si no (orientado-al-sur y frente-bloqueado) entonces inicio
        paso;
        contar-los-zumbadores(sucede(n));
      fin sino inicio
         repetir precede(n) veces inicio
             tachar;
         fin;
    fin;
fin;

define-nueva-instruccion dejar como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        dejar;
        deja-zumbador;
     fin sino inicio
        ir-1-1;
    fin;
fin;
    inicia-ejecucion
    ir-1-1;
    contar-los-zumbadores(0);
    dejar;
        apagate;
    termina-ejecucion
finalizar-programa
