iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion bloque como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            gira-izquierda;
            avanza;
        fin;
        mientras no junto-a-zumbador hacer inicio
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                gira-izquierda;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoger como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger;
            bloque;
        fin;
    fin;

    define-nueva-instruccion final como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            final;
            deja-zumbador;
        fin sino inicio
            ir11;
        fin;
    fin;

    define-nueva-instruccion cuenta(n) como inicio
        si no orientado-al-sur o frente-libre entonces inicio
            si frente-libre entonces inicio
                avanza;
                cuenta(sucede(n));
            fin sino inicio
                gira-izquierda;
                cuenta(n);
            fin;
        fin sino inicio
            este;
            repetir precede(precede(n)) veces inicio
                recoger;
            fin;
            mientras junto-a-zumbador hacer coge-zumbador;
            mientras no junto-a-zumbador hacer inicio
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    gira-izquierda;
                fin;
            fin;
            final;
        fin;
    fin;

    inicia-ejecucion
        ir11;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
