iniciar-programa
    define-nueva-instruccion ir_inicio como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira-izquierda;
    fin;

    define-nueva-instruccion busca(x) como inicio
        si no(si-es-cero(x)) entonces inicio
            si frente-libre entonces inicio
                avanza;
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces inicio
                    busca(precede(x));
                fin sino inicio
                    gira-izquierda;
                    busca(x);
                fin;
            fin sino inicio
                gira-izquierda;
                busca(x);
            fin;
        fin;
    fin;

    define-nueva-instruccion adelante como inicio
        repetir 5 veces inicio
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si no-junto-a-zumbador entonces gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion cuenta(siguientes) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(siguientes));
        fin sino inicio
            adelante;
            si junto-a-zumbador entonces inicio
                busca(precede(siguientes));
            fin sino inicio
                ir_inicio;
                repetir siguientes veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ir_inicio;
        mientras junto-a-zumbador hacer inicio
            cuenta(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
