iniciar-programa
define-nueva-instruccion avanzar(n) como si si-es-cero(n) entonces mientras frente-libre hacer avanza sino repetir n veces si frente-libre entonces avanza;
define-nueva-instruccion girar(n) como repetir n veces gira-izquierda;
define-nueva-instruccion coger(n) como si si-es-cero(n) entonces mientras junto-a-zumbador hacer coge-zumbador sino repetir n veces si junto-a-zumbador entonces coge-zumbador;
define-nueva-instruccion dejar(n) como si si-es-cero(n) entonces mientras algun-zumbador-en-la-mochila hacer deja-zumbador sino repetir n veces si algun-zumbador-en-la-mochila entonces deja-zumbador;
define-nueva-instruccion al-norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion al-sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion al-este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion al-oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion comprobar4 como inicio
    mientras no((orientado-al-norte y frente-bloqueado) o junto-a-zumbador) hacer inicio
        si frente-bloqueado entonces inicio
            si orientado-al-este entonces inicio
                al-norte;
                si frente-libre entonces inicio
                    avanzar(1);
                    al-oeste;
                fin;
            fin sino inicio
                al-norte;
                si frente-libre entonces inicio
                    avanzar(1);
                    al-este;
                fin;
            fin;
        fin sino avanzar(1);
    fin;
fin;
define-nueva-instruccion comprobar3(n) como inicio
    si frente-libre entonces inicio
        avanzar(1);
        comprobar3(n);
        avanzar(1);
    fin sino inicio
        al-este;
        comprobar4;
        si no-junto-a-zumbador entonces inicio
            al-oeste;
            avanzar(0);
            al-sur;
            avanzar(0);
            si no si-es-cero(n) entonces dejar(n);
            apagate;
        fin;
        al-oeste;
        avanzar(0);
        al-sur;
        avanzar(0);
        al-norte;
    fin;
fin;
define-nueva-instruccion comprobar2(n) como inicio
    si frente-libre entonces inicio
        avanzar(1);
        comprobar2(n);
        avanzar(1);
    fin sino inicio
        al-sur;
        comprobar3(n);
        al-este;
    fin;
fin;
define-nueva-instruccion comprobar(n) como inicio
    si no-orientado-al-oeste entonces inicio
        girar(1);
        comprobar(n);
        girar(3);
    fin sino inicio
        comprobar2(n);
        al-oeste;
    fin;
fin;
define-nueva-instruccion siguiente como mientras no-junto-a-zumbador hacer si frente-bloqueado entonces girar(1) sino avanzar(1);
define-nueva-instruccion contar(n) como inicio
    si junto-a-zumbador entonces inicio
        coger(1);
        contar(sucede(n));
    fin sino inicio
        comprobar(n);
        repetir n veces inicio
            si frente-bloqueado entonces girar(1);
            avanzar(1);
            siguiente;
        fin;
        contar(0);
    fin;
fin;
    inicia-ejecucion
        al-oeste; avanzar(0);
        al-sur; avanzar(0);
        al-este;
        contar(0);
        apagate;
    termina-ejecucion
finalizar-programa
