iniciar-programa
    define-nueva-instruccion derecha como repetir 3 veces gira-izquierda;
    define-nueva-instruccion sur como inicio
        repetir 2 veces inicio
            gira-izquierda;
            mientras frente-libre hacer avanza;
        fin;
        gira-izquierda;
    fin;
    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si orientado-al-este entonces inicio
                gira-izquierda;
                si frente-libre entonces inicio
                    avanza;
                    gira-izquierda;
                fin;
            fin sino inicio
                si orientado-al-oeste entonces inicio
                    derecha;
                    si frente-libre entonces inicio
                        avanza;
                        derecha;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoge(sucede(n));
        fin sino inicio
            si frente-libre o no orientado-al-norte entonces inicio
                avanzar;
                recoge(0);
            fin sino inicio
                sur;
            fin;
            repetir n veces inicio
                deja-zumbador;
                si frente-libre entonces avanza;
            fin;
            gira-izquierda;
            sur;
        fin;
    fin;
    inicia-ejecucion
    mientras no junto-a-zumbador y frente-libre hacer avanza;
    derecha;
    recoge(0);
        apagate;
    termina-ejecucion
finalizar-programa
