iniciar-programa

define-nueva-instruccion gira-d como repetir 3 veces gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion avanza-muro como mientras frente-libre hacer avanza;
define-nueva-instruccion avanza-zumbador como mientras junto-a-zumbador hacer avanza;

define-nueva-instruccion count-rooms como
inicio
    si frente-libre o derecha-libre entonces
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            si frente-libre entonces
            inicio
                avanza;
            fin
            sino inicio
                sur;
                avanza-muro;
                este;
                avanza;
                norte;
                avanza;
            fin;
            count-rooms;
            deja-zumbador;
        fin
        sino inicio
            si frente-libre entonces
            inicio
                avanza;
                count-rooms;
            fin    
            sino inicio
                sur;
                avanza-muro;
                este;
                avanza;
                norte;
                avanza;
                count-rooms;
            fin;
        fin;
    fin
    sino inicio
        oeste;
        avanza-muro;
        sur;
        avanza-muro;
        este;
        mientras junto-a-zumbador hacer avanza;
    fin;
fin;

define-nueva-instruccion count-last como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        count-last;
        deja-zumbador;
        si frente-libre entonces avanza;
    fin
    sino inicio
        oeste;
        avanza-muro;
        sur;
        avanza-muro;
        este;
    fin;
fin;

    inicia-ejecucion
        repetir 10 veces
        inicio
            oeste;
            avanza-muro;
            norte;
            avanza;
            count-rooms;
        fin;
        oeste;
        avanza-muro;
        norte;
        avanza-muro;
        este;
        avanza-muro;
        count-last;
        apagate;
    termina-ejecucion
finalizar-programa
