iniciar-programa
    define-nueva-instruccion norte como  mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion ubicar como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        avanza;
        mientras no junto-a-zumbador hacer inicio
            si frente-bloqueado y no junto-a-zumbador entonces inicio
                apagate;
            fin;
            avanza;
        fin;
        este;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
    fin;

    define-nueva-instruccion irinicio como inicio
        sur;                                                     
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion recogeycuenta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recogeycuenta(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                recogeycuenta(0);
            fin;
            irinicio;
            repetir n veces inicio
                deja-zumbador;
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
        fin;
    fin;

    inicia-ejecucion
        mientras frente-libre o junto-a-zumbador hacer inicio
            ubicar;
            recogeycuenta(0);
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
